home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / STUTTGART / TEX-UTIL / DVIVIEW / TEXFONTS5 / !TeXFonts / NotRISCOS / italms / mf
Text File  |  1988-02-26  |  5KB  |  117 lines
  1. % This is ITALMS.MF in text format, as of Mar 31, 1986.
  2. % This file contains miscellaneous symbols of math italic fonts.
  3. % The character codes are \0100, \0140, and \0173--\0177.
  4.  
  5. cmchar "Partial differential sign";
  6. beginchar(oct"100",10u#,asc_height#,0);
  7. italcorr .7asc_height#*slant+.5curve#-1.5u#;
  8. adjust_fit(0,0);
  9. numeric top_thickness,bot_thickness,side_thickness,pull;
  10. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  11. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  12. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  13. pull=min(.25,1.5superpull);
  14. pickup fine.nib; pos2(top_thickness,90);
  15. pos3(side_thickness,0); pos4(bot_thickness,-90);
  16. pos5(side_thickness,-180); pos6(vair,-270);
  17. lft x5r=w-rt x3r=hround max(.75u,1.5u-.5side_thickness);
  18. x4=x6+.1u=x2+u=.5w;
  19. top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
  20. y5=.5[y4,y6]; top y6=vround 5/8h+o;
  21. path p; p=pulled_super_arc.l(3,4)(pull);
  22. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  23. pos7(thin_join,0); z7l=point t of p;
  24. (x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
  25. filldraw stroke pulled_super_arc.e(2,3)(pull)
  26.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  27.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  28.  & z6e{right}...{direction t of p}z7e;  % arc and bowl
  29. pos1(hair,180); pos0(flare,180);
  30. lft x0r=min(lft x2-eps,hround 1.2u);
  31. y0=vround min(.85h-.5flare,.8h+.5flare)+o;
  32. {{less_tense; bulb(2,1,0)}};  % arc and bulb
  33. math_fit(-.3x_height#*slant+.5curve#-u#,ic#-u#);
  34. penlabels(0,1,2,3,4,5,6,7); endchar;
  35.  
  36. cmchar "Lowercase italic script l";
  37. beginchar(oct"140",4.5u#+max(1.5u#,stem#),asc_height#,0);
  38. italcorr .8asc_height#*slant-u#;
  39. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  40. pos1(hair,-45); pos2(hair,0); pos3(vair,90);
  41. pos4(stem,180); pos5(vair,270); pos6(hair,315);
  42. lft x1l=hround(lft x1l-x1); rt x2r=hround(w-1.5u); x3=.5w;
  43. lft x4r=hround .5u; x5=x3+.75u; x6=x1+w+1;
  44. y1=y6=.125h; y2=.8h; top y3r=h+oo; y4=.5[y3,y5]; bot y5=-oo;
  45. filldraw stroke z1e{10u,asc_height}...z2e{up}...pulled_arc.e(3,4)
  46.  & pulled_arc.e(4,5)...z6e{10u,asc_height};  % bowl and hook
  47. math_fit(0,ic#); penlabels(1,2,3,4,5,6); endchar;
  48.  
  49. cmchar "Dotless italic letter i";
  50. beginchar(oct"173",5u#,x_height#,0);
  51. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  52. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  53. x0=0; x5=w; x2=.5w+.25u; x3=.5w-.25u;
  54. hook_in(0,1,2)(skewed); hook_out(3,4,5)(skewed);  % hooks
  55. filldraw stroke z2e--z3e;  % stem
  56. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  57. penlabels(0,1,2,3,4,5); endchar;
  58.  
  59. cmchar "Dotless italic letter j";
  60. beginchar(oct"174",5.5u#,x_height#,desc_depth#);
  61. italcorr x_height#*slant+.5stem#-2u#;
  62. adjust_fit(if monospace:2u# else: 0 fi, 0); pickup fine.nib;
  63. x0=0; x2=x3; pos3(stem,0); lft x3l=hround(w-2u-.5stem);
  64. hook_in(0,1,2);  % opening hook
  65. pos4(vair,-90); pos5(hair,-180); pos6(flare,-180);
  66. bot y3=-1/3d; bot y4r=-d-oo; y6-.5flare=-vround.9d;
  67. x4=1/3(w-u); lft x5r=min(hround-.5u,lft x5r+x4-x5l-eps);
  68. filldraw stroke z2e---z3e...{left}z4e;  % stem and arc
  69. bulb(4,5,6);  % bulb
  70. math_fit(desc_depth#*slant,ic#); penlabels(0,1,2,3,4,5,6); endchar;
  71.  
  72. cmchar "Weierstrass p";
  73. beginchar(oct"175",11u#,x_height#,desc_depth#);
  74. italcorr .7x_height#*slant+.5stem#-u# if math_fitting:-.5u# fi;
  75. adjust_fit(0,0); pickup fine.nib;
  76. numeric theta; theta=90-angle(8u,h); slope:=-h/8u;  % angle at middle
  77. pos2(vair,-90); pos1(vstem,theta); pos7(vair,-90);
  78. x2+.5u=x1=x7-.5u=3u; top y2l=h+o; bot y7r=-d-o; y1=.4[-d,h];
  79. lft x3l=hround .5u; rt x6r=hround max(rt x7+.5,.5w-.25u);
  80. x3r-x3l=x6r-x6l=(hround .5[vair,vstem])-fine;
  81. ellipse_set(2l,3l,4l,1l); ellipse_set(2r,3r,4r,1r); y3=y3r;
  82. ellipse_set(7l,6l,5l,1l); ellipse_set(7r,6r,5r,1r); y6=y6r;
  83. filldraw stroke super_arc.e(2,3) & z3e{down}
  84.  ..z4e---z5e..z6e{down} & super_arc.e(6,7);  % flourish
  85. pos8(hair,180); pos9(vair,90); pos10(stem,0);
  86. pos11(vair,-90); pos12(hair,-180); pos13(.3[hair,flare],-180);
  87. rt x10r=hround(w-1.5u+.5stem); lft x12r=hround(.5w-.5u);
  88. rt x8l=hround 2.25u; x9=x11=max(x12l+eps,.5w+1.5u);
  89. y8=0; top y9r=vround(.9h+o); y10=.5[y9,y11]; bot y11r=-oo;
  90. filldraw stroke z7e{left}...z8e{up}...pulled_arc.e(9,10)
  91.  & pulled_arc.e(10,11);  % stem and bowl
  92. y13-.5(.6[hair,flare])=.15h; bulb(11,12,13);  % bulb
  93. math_fit(0,ic#); penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
  94.  
  95. cmchar "Arrow (vector) accent";
  96. beginchar(oct"176",9u#,asc_height#+.5rule_thickness#,0);
  97. italcorr .7[x_height#,asc_height#]*slant;
  98. adjust_fit(0,0); pickup rule.nib;
  99. lft x1=hround .5u; x2=w-x1; y1=y2=good.x .7[x_height,asc_height];
  100. draw z1--z2;  % bar
  101. rt x3=rt x4=hround(x2-u);
  102. y3=y2+.3(asc_height-x_height); y4=y2-.3(asc_height-x_height);
  103. draw z3{x2-x3,2(y2-y3)}...{2(x2-x3),y2-y3}z2;  % upper point
  104. draw z4{x2-x4,2(y2-y4)}...{2(x2-x4),y2-y4}z2;  % lower point
  105. labels(1,2,3,4); endchar;
  106.  
  107. cmchar "Tie accent";
  108. beginchar(oct"177",5u#,asc_height#,0);
  109. italcorr 4/9[x_height#,asc_height#]*slant+4.5u#+2letter_fit#+.5hair#;
  110. adjust_fit(if monospace:2u#,2u# else:serif_fit#,serif_fit# fi);
  111. pickup fine.nib; pos1(hair,180); pos2(vround 1/5[vair,stem],90); pos3(hair,0);
  112. lft x1r=hround(.5w-.5hair); x2=.5[x1,x3];
  113. rt x3r=hround(w+4u+2letter_fit+.5hair);
  114. y1=y3=4/9[x_height,asc_height]; top y2r=vround 8/9[x_height,asc_height];
  115. filldraw stroke super_arc.e(1,2) & super_arc.e(2,3);  % arc
  116. penlabels(1,2,3); endchar;
  117.